返回主页 单片机教程XL2000开发板 单片机学习 自制编程器 单片机资料 软件下载 电子技术产品介绍如何购买 论坛


;/********************************************************************************
;* 标题: xl系列单片机实验仪演示程序 矩阵键盘数码管显示键值 *
;* 文件: LEDJZ.asm *
;* 日期: 2006-1-5 *
;* 版本: 3.0 (试验通过版)可用xl600-xl1000单片机综合试验仪试验 *
;* 邮箱: sxj1974@163.com *
;* 网站: http://www.51c51.com www.8951.com *
;********************************************************************************
;* 描述: * 
;* 矩阵键盘数码管显示键值 * 
;* 矩阵键盘定义: *
;* P1.0-P1.3为列线,P1.4-P1.7为行线 * 
;* 喇叭接P3.7口 矩阵键盘P1口, 数码管数据P0口,数码管控制P2口 * 
;********************************************************************************
;* 【版权】 Copyright(C)深圳市学林电子有限公司 www.51c51.com *
;* 【声明】 此程序仅用于学习与参考,引用请注明版权和作者信息! *
;* 【技术支持】请访问http://www.51c51.com/bbs/ 官方论坛 *
;********************************************************************************/
BEEP EQU P3.7
;------------------------------------------------------
ORG 0080H
JMP MAIN
;------------------------------------------------------
MAIN: MOV SP,#60H
MOV 30H,#00H 
LOOP1:
CALL KEY_IN
CALL KEY_PLAER
JMP LOOP1
;-----------------------------------------------------
KEY_IN: MOV P1,#0F0H ;置列线为0,行线为1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列线为1,行线为0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位与低四位重新组合
CJNE A,#0FFH,KEY_IN1 ;0FFH为末按键
RET
KEY_IN1: MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH ;
KEY_IN2: INC R3
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到,取顺序码 
MOV 30H,A
CALL BEEP_BL
RET
KEY_IN3: CJNE A,#0FFH,KEY_IN2 ;末完,继续查
RET ;0FFH为结束码
;----------------------------------------------
;蜂鸣器响一声子程序
;----------------------------------------------
BEEP_BL:
MOV R6,#100
BL1: CALL DEX1
CPL BEEP
DJNZ R6,BL1
MOV R5,#25
CALL DELAY
RET
DEX1: MOV R7,#180
DEX2: NOP
DJNZ R7,DEX2
RET
DELAY: ;延时R5×10MS
MOV R6,#50
DELAY1: MOV R7,#100
DJNZ R7,$
DJNZ R6,DELAY1
DJNZ R5,DELAY
RET
;-----------------------------------------------------
KEYTABLE:
DB 0eeH ,077H,0B7H,0D7H, 07bh,0bbh,0dbh ,07dh,0bdh,0ddh, 0e7h,0ebh,0edh, 07eh,0beh,0deh, 0ffH
;-----------------------------------------------------
;键值显示子程序
;使用一个数码管显示
;-----------------------------------------------------
KEY_PLAER:

MOV A,30H
MOV DPTR,#TAB ;取段码表地址
MOVC A,@A+DPTR ;查显示数据对应段码
MOV P0,A ;段码放入P0口
CLR P2.7 ;第一个数码管亮
RET 
;-----------------------------------------------------
TAB:
DB 28h,7eh,0a2h,62h,74h,61h,21h,7ah,20h,60h,30h,25h,0a9h,26h,0a1h,0b1h;数码管代码
;-----------------------------------------------------
END